Index · Object → RefCounted → MultiplayerAPI → MultiplayerAPIExtension

MultiplayerAPIExtension

Base class used for extending the MultiplayerAPI.

Class Description

This class can be used to extend or replace the default MultiplayerAPI implementation via script or extensions.

The following example extend the default implementation (SceneMultiplayer) by logging every RPC being made, and every object being configured for replication.

extends MultiplayerAPIExtension
class_name LogMultiplayer

# We want to extend the default SceneMultiplayer.
var base_multiplayer = SceneMultiplayer.new()

func _init():
	# Just passthrough base signals (copied to var to avoid cyclic reference)
	var cts = connected_to_server
	var cf = connection_failed
	var sd = server_disconnected
	var pc = peer_connected
	var pd = peer_disconnected
	base_multiplayer.connected_to_server.connect(func(): cts.emit())
	base_multiplayer.connection_failed.connect(func(): cf.emit())
	base_multiplayer.server_disconnected.connect(func(): sd.emit())
	base_multiplayer.peer_connected.connect(func(id): pc.emit(id))
	base_multiplayer.peer_disconnected.connect(func(id): pd.emit(id))

func _poll():
	return base_multiplayer.poll()

# Log RPC being made and forward it to the default multiplayer.
func _rpc(peer: int, object: Object, method: StringName, args: Array) -> Error:
	print("Got RPC for %d: %s::%s(%s)" % [peer, object, method, args])
	return base_multiplayer.rpc(peer, object, method, args)

# Log configuration add. E.g. root path (nullptr, NodePath), replication (Node, Spawner|Synchronizer), custom.
func _object_configuration_add(object, config: Variant) -> Error:
	if config is MultiplayerSynchronizer:
		print("Adding synchronization configuration for %s. Synchronizer: %s" % [object, config])
	elif config is MultiplayerSpawner:
		print("Adding node %s to the spawn list. Spawner: %s" % [object, config])
	return base_multiplayer.object_configuration_add(object, config)

# Log configuration remove. E.g. root path (nullptr, NodePath), replication (Node, Spawner|Synchronizer), custom.
func _object_configuration_remove(object, config: Variant) -> Error:
	if config is MultiplayerSynchronizer:
		print("Removing synchronization configuration for %s. Synchronizer: %s" % [object, config])
	elif config is MultiplayerSpawner:
		print("Removing node %s from the spawn list. Spawner: %s" % [object, config])
	return base_multiplayer.object_configuration_remove(object, config)

# These can be optional, but in our case we want to extend SceneMultiplayer, so forward everything.
func _set_multiplayer_peer(p_peer: MultiplayerPeer):
	base_multiplayer.multiplayer_peer = p_peer

func _get_multiplayer_peer() -> MultiplayerPeer:
	return base_multiplayer.multiplayer_peer

func _get_unique_id() -> int:
	return base_multiplayer.get_unique_id()

func _get_remote_sender_id() -> int:
	return base_multiplayer.get_remote_sender_id()

func _get_peer_ids() -> PackedInt32Array:
	return base_multiplayer.get_peers()

Then in your main scene or in an autoload call SceneTree.set_multiplayer() to start using your custom MultiplayerAPI:

# autoload.gd
func _enter_tree():
	# Sets our custom multiplayer as the main one in SceneTree.
	get_tree().set_multiplayer(LogMultiplayer.new())

Native extensions can alternatively use the MultiplayerAPI.set_default_interface() method during initialization to configure themselves as the default implementation.

Properties

Inherited from MultiplayerAPI (1)

Methods

func _get_multiplayer_peer() -> MultiplayerPeer

Called when the MultiplayerAPI.multiplayer_peer is retrieved.

func _get_peer_ids() -> PackedInt32Array

Callback for MultiplayerAPI.get_peers().

func _get_remote_sender_id() -> int

Callback for MultiplayerAPI.get_remote_sender_id().

func _get_unique_id() -> int

Callback for MultiplayerAPI.get_unique_id().

func _object_configuration_add(object: Object, configuration: Variant) -> Error

Callback for MultiplayerAPI.object_configuration_add().

func _object_configuration_remove(object: Object, configuration: Variant) -> Error

Callback for MultiplayerAPI.object_configuration_remove().

func _poll() -> Error

Callback for MultiplayerAPI.poll().

func _rpc(peer: int, object: Object, method: StringName, args: Array) -> Error

Callback for MultiplayerAPI.rpc().

func _set_multiplayer_peer(multiplayer_peer: MultiplayerPeer) -> void

Called when the MultiplayerAPI.multiplayer_peer is set.

Inherited from MultiplayerAPI (12)
func get_unique_id() -> int
func is_server() -> bool
func object_configuration_add(object: Object, configuration: Variant) -> Error
func object_configuration_remove(object: Object, configuration: Variant) -> Error
func poll() -> Error
func rpc(peer: int, object: Object, method: StringName, arguments: Array = []) -> Error
func set_default_interface(interface_name: StringName) -> void
Inherited from RefCounted (4)
func init_ref() -> bool
func reference() -> bool
func unreference() -> bool
Inherited from Object (62)
func _get(property: StringName) -> Variant
func _get_property_list() -> Dictionary[]
func _init() -> void
func _iter_get(iter: Variant) -> Variant
func _iter_init(iter: Array) -> bool
func _iter_next(iter: Array) -> bool
func _notification(what: int) -> void
func _set(property: StringName, value: Variant) -> bool
func _to_string() -> String
func _validate_property(property: Dictionary) -> void
func add_user_signal(signal: String, arguments: Array = []) -> void
func call(method: StringName) -> Variant
func callv(method: StringName, arg_array: Array) -> Variant
func cancel_free() -> void
func connect(signal: StringName, callable: Callable, flags: int = 0) -> Error
func disconnect(signal: StringName, callable: Callable) -> void
func emit_signal(signal: StringName) -> Error
func free() -> void
func get(property: StringName) -> Variant
func get_class() -> String
func get_incoming_connections() -> Dictionary[]
func get_indexed(property_path: NodePath) -> Variant
func get_meta(name: StringName, default: Variant = null) -> Variant
func get_meta_list() -> StringName[]
func get_method_list() -> Dictionary[]
func get_property_list() -> Dictionary[]
func get_signal_connection_list(signal: StringName) -> Dictionary[]
func get_signal_list() -> Dictionary[]
func has_meta(name: StringName) -> bool
func has_method(method: StringName) -> bool
func has_signal(signal: StringName) -> bool
func is_class(class: StringName) -> bool
func is_connected(signal: StringName, callable: Callable) -> bool
func notification(what: int, reversed: bool = false) -> void
func remove_meta(name: StringName) -> void
func remove_user_signal(signal: StringName) -> void
func set(property: StringName, value: Variant) -> void
func set_block_signals(enable: bool) -> void
func set_deferred(property: StringName, value: Variant) -> void
func set_indexed(property_path: NodePath, value: Variant) -> void
func set_message_translation(enable: bool) -> void
func set_meta(name: StringName, value: Variant) -> void
func set_script(script: Variant) -> void
func set_translation_domain(domain: StringName) -> void
func to_string() -> String
func tr(message: StringName, context: StringName = &"") -> String
func tr_n(message: StringName, plural_message: StringName, n: int, context: StringName = &"") -> String

Signals

Inherited from MultiplayerAPI (5)
signal peer_connected(id: int)
Inherited from Object (2)